软件名称：[B]【RSI划线指标】可以准确判断趋势顶底的指标及用法图文说明[/B]
软件类型：股票池 - 通达信公式
运行平台：Win7/Vista/WinXP/Win2003/
软件语言：简体中文
授权方式：共享版
软件大小：0 Bytes
更新时间：2009-09-09 08:33:00
软件简介:

用来判断趋势顶底一目了然。好比轰-6换大功率涡扇发动机配巡航导弹！
1．把传统指标RSI修饰美化。
2．加压力支撑线的自动划线功能。
3．图标明示顶底背离。
4．指标标题栏文字，颜色，数字明确，无多余显示。
5．指标图案颜色柔性配置。
源自传统，灵自理想，精装后回报理想！！！
有曰：人在江湖操，一生梦宝刀。我曰：人在江湖混，一根打狗棍！
附图4张说明用法。
-------------------------------------------------------------------------------------------------------
{RSI划线}
{N1:2,120,5;N2:2,250,10;N3:2,500,20;}
{参数:P:1,20,3;}{支撑压力线的周期参数 P可调}
STICKLINE(C>0,0,30,10,0),COLOR353535;
STICKLINE(C>0,30,50,10,0),COLOR454545;
STICKLINE(C>0,50,80,10,0),COLOR555555;
STICKLINE(C>0,80,95,10,0),COLOR757575;
强弱线:50,LINETHICK2,COLOR858585;
警示线:80,POINTDOT,COLORCYAN;
减仓线:90,COLOR00AA55,LINETHICK2;
清仓线:95,COLOR0000AA,LINETHICK2;
LC:=REF(CLOSE,1);
RSI5:SMA(MAX(CLOSE-LC,0),N1,1)/SMA(ABS(CLOSE-LC),N1,1)*100,NODRAW,COLORFFAAFF;
RSI10:SMA(MAX(CLOSE-LC,0),N2,1)/SMA(ABS(CLOSE-LC),N2,1)*100,NODRAW,COLORDDAADD;
RSI20:SMA(MAX(CLOSE-LC,0),N3,1)/SMA(ABS(CLOSE-LC),N3,1)*100,NODRAW,COLORAA99AA;
DRAWBAND(RSI5,RGB(195,125,195),RSI10,RGB(0,130,50));
DRAWBAND(RSI10,RGB(165,95,165),RSI20,RGB(0,100,20));
{金叉死叉}
金叉:CROSS(RSI5,RSI20) AND CROSS(RSI10,RSI20),COLORRED,NODRAW;
DRAWTEXT(金叉,RSI5,'←'),COLORRED;
死叉:CROSS(RSI20,RSI10) AND CROSS(RSI20,RSI5),COLORGREEN,NODRAW;
DRAWTEXT(死叉,RSI5,'←'),COLORGREEN;
{RSI顶底背离}
RS:=BARSLAST(REF(CROSS(RSI20,RSI5),1));
RS1:=REF(CLOSE,RS+1)<CLOSE AND REF(RSI5,RS+1)>RSI5 AND CROSS(RSI20,RSI5);
顶背离:IF(RS1,RSI5,DRAWNULL),CIRCLEDOT,COLORFFCC00;
STICKLINE(RS1,RSI5,RSI5*0.9,0,0),COLORFFCC00;
DRAWTEXT(RS1,RSI5*0.9,'顶背离'),COLORFFCC00;
S1:=BARSLAST(REF(CROSS(RSI5,RSI20),1));
S1A:=REF(CLOSE,S1+1)>CLOSE AND RSI5>REF(RSI5,S1+1) AND
CROSS(RSI5,RSI20);
底背离:IF(S1A,RSI5,DRAWNULL),CIRCLEDOT,COLOR6699FF;
STICKLINE(S1A,RSI5,RSI5*1.1,0,0),COLOR6699FF;
DRAWTEXT(S1A,RSI5*1.1,'底背离'),COLOR6699FF;
{RSI划线}
OB:=RSI5;
A1:=REF(OB,P)=HHV(OB,2*P+1);
B1:=FILTER(A1,P);
C1:=BACKSET(B1,P+1);
D1:=FILTER(C1,P);{高点}
A2:=REF(OB,P)=LLV(OB,2*P+1);
B2:=FILTER(A2,P);
C2:=BACKSET(B2,P+1);
D2:=FILTER(C2,P);{低点}
R11:=BACKSET(ISLASTBAR,BARSLAST(D1)+1);
S11:=R11>REF(R11,1);
压力线:DRAWLINE(D1,OB,S11,OB,1),LINETHICK1,COLORCC33CC;
T11:=BACKSET(ISLASTBAR,BARSLAST(D2)+1);
U11:=T11>REF(T11,1);
支撑线:DRAWLINE(D2,OB,U11,OB,1),COLOR00CCCC;

DRAWTEXT(CURRBARSCOUNT=30,25,'强弱用来看趋势 背离用来看顶底'),COLORCC99FF;
DRAWTEXT(CURRBARSCOUNT=30,15,'支撑压力辨起落 设定周期参数 P'),COLORCC99FF;
-----------------------------------------------------------------------------------------------------
附图4张说明功能和用法：

[url=http://www.goodgupiao.com/soft/xuangugongshi/sort011/down-5922.html][B]【RSI划线指标】可以准确判断趋势顶底的指标及用法图文说明[/B][/url]