您现在的位置:好股网 >> 股票公式 >> 金字塔公式

金字塔汇集各种模型编写方法

[下载地址]
  • 更新时间:2013-03-01 08:47:00
  • 指标功能:国产软件
  • 公式大小:0 Bytes
  • 解压密码:goodgupiao
  • 推荐星级:
  • 授权方式:共享版
  • 公式分类:金字塔公式
  • 指标类型:简体中文
  • 运行环境:Win2000/WinXP/Win2003/
  • 所需积分:0
  • 相关Tags:

金字塔汇集各种模型编写方法介绍

好股网(www.goodgupiao.com)提示:您正在下载的是:金字塔汇集各种模型编写方法

一,如何把“K线走完模式”的模型转换成“固定轮询模式”的模型

以便把各个模型放在同一个框架内进行图表程序化交易

举例:

均线交叉模型(K线走完模型):

runmode:0;

ma5:=ma(c,5);

ma20:=ma(c,20);

entertime:=time>100000 and time<144500;

if holding>0 and ma5<ma20 then sell(1,1,market);

if holding<0 and ma5>ma20 then sellshort(1,1,market);

if holding=0 and ma5>ma20 and entertime then buy(1,1,market);

if holding=0 and ma5<ma20 and entertime then buyshort(1,1,market);

if time>=150000 then begin

sell(1,1,market);

sellshort(1,1,market);

end

简单的改法,自然是把各个条件“过去化”,如:ma5 改为 ref(ma(c,5),1);但这种方法碰到大型的、复杂的模型时,容易出错

可采用这种方法,把holding用全局变量cc替换,然后加入红色部分代码,红色部分代码要放在信号语句的前面:

runmode:0;

variable:cc=0;

ma5:=ma(c,5);

ma20:=ma(c,20);

entertime:=time>100000 and time<144500;

if holding>0 and cc<=0 then sell(1,1,limitr,o);

if holding<0 and cc>=0 then sellshort(1,1,limitr,o);

if holding=0 and cc>0 then buy(1,1,limitr,o);

if holding=0 and cc<0 then buyshort(1,1,limitr,o);

if cc>0 and ma5<ma20 then cc:=0;

if cc<0 and ma5>ma20 then cc:=0;

if cc=0 and ma5>ma20 and entertime then cc:=1;

if cc=0 and ma5<ma20 and entertime then cc:=-1;

if time>=150000 then begin

cc:=0;

end

那么,如果是 K线走完模式和盘中模式并存,怎么做呢?也简单,就是在“开盘价下单语句”后面加入蓝色部分的“盘中下单语句”就行了

如下:

runmode:0;

variable:zs=0,cc=0;

ma5:=ma(c,5);

ma20:=ma(c,20);

entertime:=time>100000 and time<144500;

if holding>0 and cc<=0 then sell(1,1,limitr,o);

if holding<0 and cc>=0 then sellshort(1,1,limitr,o);

if holding=0 and cc>0 then buy(1,1,limitr,o);

if holding=0 and cc<0 then buyshort(1,1,limitr,o);

if cc>0 and l<zs then begin

sell(1,1,limitr,min(o,zs-0.6));

cc:=0;

end

if cc<0 and h>zs then begin

sellshort(1,1,limitr,max(o,zs+0.6));

cc:=0;

end

if cc>0 and ma5<ma20 then cc:=0;

if cc<0 and ma5>ma20 then cc:=0;

if cc=0 and ma5>ma20 and entertime then begin

cc:=1;

zs:=c-10;

end

if cc=0 and ma5<ma20 and entertime then begin

cc:=-1;

zs:=c+10;

end

if time>=150000 then begin

cc:=0;

end


二、移动止损的编写方法:
还是以之前的模型为例,希望加入移动止损,即:开仓后的最高点回落10个点要盘中止损离场
加入一个全局变量 hl,记录开多后的最高点,开空后的最低点:
runmode:0;
variable:zs=0,cc=0,hl=0;
ma5:=ma(c,5);
ma20:=ma(c,20);
entertime:=time>100000 and time<144500;
if holding>0 and cc<=0 then sell(1,1,limitr,o);
if holding<0 and cc>=0 then sellshort(1,1,limitr,o);
if holding=0 and cc>0 then buy(1,1,limitr,o);
if holding=0 and cc<0 then buyshort(1,1,limitr,o);
if cc>0 and l<zs then begin
sell(1,1,limitr,min(o,zs-0.6));
cc:=0;
end
if cc<0 and h>zs then begin
sellshort(1,1,limitr,max(o,zs+0.6));
cc:=0;
end
if cc>0 and ma5<ma20 then cc:=0;
if cc<0 and ma5>ma20 then cc:=0;
if cc=0 and ma5>ma20 and entertime then begin
cc:=1;
zs:=c-10;
hl:=h;
end
if cc=0 and ma5<ma20 and entertime then begin
cc:=-1;
zs:=c+10;
hl:=l;
end
if cc>0 and h>hl then begin//创新高后,上移hl
hl:=h;
zs:=hl-10;
end
if cc<0 and l<hl then begin//创新低后,下移hl
hl:=l;
zs:=hl+10;
end
if time>=150000 then begin
cc:=0;
end

三、逐K线模式的模型,用免费版下单交易的方法
runmode:0;
variable:cc=0;
ma5:=ma(c,5);
ma20:=ma(c,20);
entertime:=time>100000 and time<144500;
exitlong:cc<>1,tfilter;
exitshort:cc<>-1,tfilter;
enterlong:ref(cc,1)<>1 and cc=1,tfilter;
entershort:ref(cc,1)<>-1 and cc=-1,tfilter;
if cc>0 and ma5<ma20 then cc:=0;
if cc<0 and ma5>ma20 then cc:=0;
if cc=0 and ma5>ma20 and entertime then cc:=1;
if cc=0 and ma5<ma20 and entertime then cc:=-1;
if time>=150000 then cc:=0;

原理是,用全局变量cc记录仓位,然后根据仓位的变化情况来确定下单信号


四、日内满仓反手的写法
因为满仓的情况下,要等平仓单成交、保证金释放后,开仓下单才能成功。
用系统自带的orderqueue在平仓单没有第一时间成交的情况下有一定的局限性,可用如下的方法:
runmode:0;
input:cw(3,1,10,1);
variable:cc=0;
ma5:=ma(c,5);
ma20:=ma(c,20);
entertime:=time>100000 and time<144500;
if holding>0 and cc<=0 then sell(1,cw,limitr,o);
if holding<0 and cc>=0 then sellshort(1,cw,limitr,o);
//此方法撤单和追单时间要控制在出信号的K线时间以内
if holding=0 and cc>0 and cw+tholding2>=cw then buy(1,cw,limitr,o);//平空成交后,"cw+tholding2>=cw "才会成立并开多
if holding=0 and cc<0 and cw-tholding2>=cw then buyshort(1,cw,limitr,o);//平多成交后,"cw-tholding2>=cw "才会成立并开空
if cc>0 and ma5<ma20 then cc:=0;
if cc<0 and ma5>ma20 then cc:=0;
if cc=0 and ma5>ma20 and entertime then cc:=1;
if cc=0 and ma5<ma20 and entertime then cc:=-1;
if time>=150000 then begin
cc:=0;
end

五、自行计算最大回撤的方法,放到逐K线模式的模型最后面即可:

zichan:asset,noaxis;
if barpos=1 then begin
MaxAsset:=zichan;
Maxhc:=0; end
if zichan>MaxAsset then MaxAsset:=zichan;
if MaxAsset-zichan>Maxhc then Maxhc:=MaxAsset-zichan;
最大回撤:Maxhc,linethick0;
交易次数:totaltrade,linethick0;
正确率:percentwin,linethick0;
//这里的变量"MaxAsset”、"Maxhc" 其实是全局变量,可不必声明。有重新赋值变量值才会改变

六、“后台下单模板”,可用于各种模型。不会写后台模型的塔友,以后不用写了,复制此模板即OK
只要把此模板放在 模型的最后面,就可以后台全自动化交易了。此方法还有一个好处,即使用固定轮询模式,也不会漏单
注意:把800988替换成自己的账户,按ctrl+H 进行替换
有个性化需求的,也可在此模板上的基础上定制。不会的可以找我
runmode:0;
Globalvariable:hold=drawnull;
……//这里添加上你自己的模型
……//这里添加上你自己的模型
cc800988:=holding;//这句放在信号稳定的地方,即时下单的,就放下单语句的后面,K线走完下单的就放下单语句的前面
drawtextex(1,1,800,0,'虚拟持仓为:'+numtostr(cc800988,0));//在图表上输出虚拟持仓以便监控
if not(islastbar) or workmode<>1 then exit;
xiadan800988:=cc800988-hold;
if xiadan800988>0.5 then begin
cang:=min(xiadan800988,abs(hold));
if hold<0 then tsellshort(1,cang,mkt,0,0,'800988'),allowrepeat;
cang:=xiadan800988+min(hold,0);
if cang>0 then tbuy(1,cang,mkt,0,0,'800988'),allowrepeat;
end
if xiadan800988<-0.5 then begin
cang:=min(abs(xiadan800988),abs(hold));
if hold>0 then tsell(1,cang,mkt,0,0,'800988'),allowrepeat;
cang:=abs(xiadan800988)-max(hold,0);
if cang>0 then tbuyshort(1,cang,mkt,0,0,'800988'),allowrepeat;
end
hold:=cc800988;


好股网(www.goodgupiao.com)提醒您:股市有风险,投资需谨慎。
金字塔汇集各种模型编写方法下载地址
下载必看(为了保障您的权益,请在下载指标前务必看清楚相关说明)
  • 网站注册、找回密码、下载过程遇到问题,请您联系,我们会在第一时间指导反馈。
  • 积分指标使用遇到问题,如指标安装不成功或指标介绍的特点与实际发布的不符,请联系好股网客服进行问题处理。
  • 指标来源网络收集和会员提供,不保证提供的下载资源的准确性、安全性和完整性。请自行谨慎甄别公式相关描述后再下载,好股网不保障和承担使用该指标公式投资带来的一切损失。
  • 指标仅供学习和研究使用,不得用于商业或者非法用途。本站对于提供下载的指标、软件等不拥有任何权利,其版权归该下载资源的合法拥有者所有,如有侵犯您的版权,请查看《侵权投诉》,本站将移除相关内容。
更多最新置顶指标公式
相关说明
  • 目前市场常用软件有通达信、大智慧等,通达信版本从高到低的指标格式有tn6、tne、tni,股票池格式为XML。大智慧指标格式有fnc,股票池格式为XML。
  • 通达信指标导入安装快捷方法:快捷键CTRL+F > 公式管理器面板 导入公式 > 选择要导入的公式 打开 > 在导入公式面板中 勾选公式,确定。
  • 通达信指标呈现快捷方法:点击指标面板要显示的主图或副图,快捷键CTRL+I > 选择指标,确定。
  • alg格式股票公式,仅仅可以用飞狐交易师股票软件引入使用;
  • fnc格式股票公式,可以用大智慧新一代高速行情分析系统股票软件使用,少部分可以用分析家股票软件引入使用;
  • exp格式股票公式,仅可以用大智慧经典版股票软件引入使用;
  • tnctni格式股票公式,仅可以用通达信新引入使用,例如可以用通达信股票软件引入使用;
  • tn6格式公式,仅可以用通达信公式编辑器5.0版导入,高版本兼容低版本;
  • hxf格式股票公式,仅可以用同花顺股票软件引入使用。
  • 如果引入公式的时候,发现公式名称栏空白,调整电脑时间到1997年,能出现公式名称并正常显示,可能是公式使用期限已过。
  • 如果您发现下载链接错误,请点击报告错误谢谢!